ESP32 + 继电器模块接入 ThingsCloud

约 2254 字大约 8 分钟

ESP32 + 继电器模块接入 ThingsCloud

ESP32 是乐鑫公司推出的 WiFi 芯片，它不仅支持 WiFi 和 BLE，还可以作为可编程的 MCU，通过 Espressif IDF、Arduino 等框架编写固件，用于非常广泛的物联网场景。

这个教程我们分享如何在 Arduino IDE 中使用 ThingsCloud ESP SDK，为 ESP32 开发固件程序，通过 ThingsCloud 物联网平台远程控制继电器状态，并利用 ThingsCloud 强大的零代码应用开发工具，为用户生成 App，并支持 WiFi 配网。

该示例不仅支持 ESP32 芯片，同样支持：ESP8266、ESP32-S2、ESP32-S3、ESP32-C3。

温馨提示

在学习本教程之前，您需要具备一些基础知识，包括：

如何在 Arduino IDE 中开发和上传 ESP32 固件。
Arduino 框架下的单片机编程基础。
C 语言基础

这些内容不在本教程的范围内，请您自行学习，相关的学习资源很多。

硬件部分准备

连线示意图

我们使用的继电器模块有3个引脚：

引脚	说明
VCC	3.3-5V DC
GND	接 ESP32 的 GND
IN	输入引脚，低电平信号触发继电器闭合

与 ESP32 开发板的接线方式，如下图：

示例中我们将继电器模块的输入引脚接到了 ESP32 的 GPIO5 上，您也可以使用其它可用的 GPIO 引脚，并在代码中修改引脚编号。

在 Arduino 中安装依赖库

安装 ThingsCloud ESP SDK

详细安装方法，请浏览在 Arduino IDE 中安装 ThingsCloud ESP SDK

使用示例代码

请确保已更新 SDK 到最新版本，在 Arduino 示例代码中，找到 10.IoT_Tutorials > relay_control 示例代码。

以下为完整代码：

#include <ThingsCloudWiFiManager.h>
#include <ThingsCloudMQTT.h>

//======================================================
// 设置 ssid / password，连接到你的 WiFi AP
const char *ssid = "";
const char *password = "";
// 在 ThingsCloud 控制台的设备详情页中，复制以下设备连接信息
// https://console.thingscloud.xyz
#define THINGSCLOUD_MQTT_HOST ""
#define THINGSCLOUD_DEVICE_ACCESS_TOKEN ""
#define THINGSCLOUD_PROJECT_KEY ""
//======================================================

ThingsCloudMQTT client(
  THINGSCLOUD_MQTT_HOST,
  THINGSCLOUD_DEVICE_ACCESS_TOKEN,
  THINGSCLOUD_PROJECT_KEY);

// 设置继电器的输入引脚
#define RELAY_PIN 5

void setup() {
  Serial.begin(115200);

  pinMode(RELAY_PIN, OUTPUT);
  // 初始断开继电器，输出高电平
  digitalWrite(RELAY_PIN, HIGH);

  // 允许 SDK 的日志输出
  client.enableDebuggingMessages();

  // 连接 WiFi AP
  client.setWifiCredentials(ssid, password);
}

void handleAttributes(const JsonObject &obj) {
  if (obj.containsKey("relay")) {
    // 接收到下发的 relay 属性
    if (obj["relay"] == true) {
      // 闭合继电器，输出低电平
      digitalWrite(RELAY_PIN, LOW);
      Serial.println("relay switch to ON");
    } else {
      // 断开继电器，输出高电平
      digitalWrite(RELAY_PIN, HIGH);
      Serial.println("relay switch to OFF");
    }
  }
}

// 必须实现这个回调函数，当 MQTT 连接成功后执行该函数。
void onMQTTConnect() {

  // 订阅获取属性的回复消息
  client.onAttributesGetResponse([](const String &topic, const JsonObject &obj) {
    if (obj["result"] == 1) {
      handleAttributes(obj["attributes"]);
    }
  });

  // 订阅云平台下发属性的消息
  client.onAttributesPush([](const JsonObject &obj) {
    handleAttributes(obj);
  });

  // 读取设备在云平台上的属性，用于初始化继电器状态。
  // 云平台回复的属性会进入上边 client.onAttributesGetResponse 接收的消息。
  client.getAttributes();
}

void loop() {
  client.loop();
}

设置代码中的参数

示例代码中，只需要补全以下两处参数。

WiFi 连接参数

这个教程中我们使用的是指定 WiFi 连接参数的方式，需要修改以下部分：

// 设置 ssid / password，连接到你的 WiFi AP
const char *ssid = "";
const char *password = "";

请修改为您自己的 WiFi 连接参数，修改后大致是这样的：

// 设置 ssid / password，连接到你的 WiFi AP
const char *ssid = "my-wifi-ap";
const char *password = "thingscloud.xyz";

ThingsCloud 设备 MQTT 地址和连接证书

接下来填写您在 ThingsCloud 的设备 MQTT 地址和连接证书，如下：

// 在 ThingsCloud 控制台的设备详情页中，复制以下设备连接信息
// https://console.thingscloud.xyz
#define THINGSCLOUD_MQTT_HOST ""
#define THINGSCLOUD_DEVICE_ACCESS_TOKEN ""
#define THINGSCLOUD_PROJECT_KEY ""

如何获得这些参数呢？首先在 ThingsCloud 控制台创建一个设备类型，这里可以直接选择标准类型中的单路网络继电器，如下图：

填写其它的信息，如下图：

接下来创建一个新设备，选择绑定到刚才创建的设备类型上。如下图：

设备创建成功后，在设备概览中，可以看到一个拨动开关，这是由设备类型的属性定义产生的。

进入设备的 连接 页面，在这里可以复制代码中需要的几个参数，如下图：

将参数补全到代码中，例如：

// 在 ThingsCloud 控制台的设备详情页中，复制以下设备连接信息
// https://console.thingscloud.xyz
#define THINGSCLOUD_MQTT_HOST "********.iot-api.com"
#define THINGSCLOUD_DEVICE_ACCESS_TOKEN "bzqsg6b7l2******"
#define THINGSCLOUD_PROJECT_KEY "VV9Z******"